# $Id: mossmap.pro 275 2008-02-22 23:40:55Z mloskot $
#
# MOSSMAP project file for qmake tool from Qt.
#
PROJECT_NAME = MOSSMAP

HEADERS = \
    about_dialog.hpp \
    main_window.hpp \
    map_widget.hpp

SOURCES = \
    main.cpp \
    about_dialog.cpp \
    main_window.cpp \
    map_widget.cpp

RESOURCES = mossmap.qrc

FORMS = \
	ui\about_dialog.ui

#
# MOSS4G Libraries Configuration
#
M4G_LIBS = ../../libs
M4G_SDK = "$${CE_SDK} ($${CE_ARCH})"
M4G_VCPROJ_DIR = msvc80ce

M4G_GDAL_DIR = $${M4G_LIBS}/gdal
M4G_GEOS_DIR = $${M4G_LIBS}/geos
M4G_PROJ4_DIR = $${M4G_LIBS}/proj4
M4G_WCELIBCEX_DIR = $${M4G_LIBS}/wcelibcex
M4G_BOOST_DIR = $${M4G_LIBS}/boost

	# PROJ.4
	LIBS += $${M4G_PROJ4_DIR}/$${M4G_VCPROJ_DIR}/$${M4G_SDK}/Debug/proj_i.lib
	deploy_proj4.sources=$${M4G_PROJ4_DIR}/$${M4G_VCPROJ_DIR}/$${M4G_SDK}/Debug/proj.dll
	deploy_proj4.path = .

	# GEOS
	LIBS += $${M4G_GEOS_DIR}/$${M4G_VCPROJ_DIR}/$${M4G_SDK}/Debug/geos_c_i.lib
	deploy_geos.sources="d:/dev/moss4g/_svn/moss4g/libs/geos/msvc80ce/Windows Mobile 5.0 Pocket PC SDK (ARMV4I)/Debug/geos_c.dll"
	deploy_geos.path = .

	# GDAL
	LIBS += $${M4G_GDAL_DIR}/$${M4G_VCPROJ_DIR}/$${M4G_SDK}/Debug/gdal_i.lib
	deploy_gdal.sources=$${M4G_GDAL_DIR}/$${M4G_VCPROJ_DIR}/$${M4G_SDK}/Debug/gdal.dll
	deploy_gdal.path = .

INCLUDEPATH += $${M4G_BOOST_DIR}/src/include
INCLUDEPATH += $${M4G_WCELIBCEX_DIR}/src
INCLUDEPATH += $${M4G_PROJ4_DIR}/src/src
INCLUDEPATH += $${M4G_GEOS_DIR}/src/source/headers
INCLUDEPATH += $${M4G_GDAL_DIR}/src/port $${M4G_GDAL_DIR}/src/gcore $${M4G_GDAL_DIR}/src/ogr $${M4G_GDAL_DIR}/src/ogr/ogrsf_frmts

DEPLOYMENT = deploy_proj4 deploy_geos deploy_gdal

#
# Configuration summary
#
message()
message("Summary of $${PROJECT_NAME} configuration for Windows CE")
message("  Qt version: $$[QT_VERSION]")
message("  Target SDK: $${CE_SDK}")
message("  Target ARCH: $${CE_ARCH}")
message()