dnl Process this file with autoconf to produce a configure script.
AC_INIT(src/ossimConfig.h.in)
AC_CONFIG_HEADER(src/ossimConfig.h)

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(fcntl.h unistd.h dbmalloc.h dlfcn.h malloc.h)

dnl check and setup defines for different compiler checks
dnl and specific output extensions.
AC_CANONICAL_SYSTEM
AC_EXEEXT
AC_OBJEXT

USE_UNIX=0
USE_WIN32=0
USE_MAC=0

USE_CYGWIN=0
USE_LINUX=0
USE_SGI=
USE_HPUX=
USE_SYSV=
USE_SVR4=
USE_AIX=
USE_SUN=
USE_SOLARIS=
USE_SUNOS=
USE_ALPHA=
USE_OSF=
USE_BSD=
USE_DARWIN=
USE_FREEBSD=
USE_OPENBSD=
USE_NETBSD=
USE_VMS=
USE_ULTRIX=

CARBON=
dnl to support a new system, you need to add its canonical name (as determined
dnl by config.sub or specified by the configure command line) to this "case"
dnl and also define the shared library flags below - search for
dnl SHARED_LIB_SETUP to find the exact place
case "${host}" in
  *-hp-hpux* )
    USE_HPUX=1
    NEEDS_D_REENTRANT_FOR_R_FUNCS=1
    SO_SUFFIX=sl
    AC_DEFINE(__OSSIM_HPUX__)
  ;;
  *-*-linux* )
    USE_LINUX=1
    AC_DEFINE(__OSSIM_LINUX__)
    TMP=`uname -m`
    if test "x$TMP" = "xalpha"; then
      USE_ALPHA=1
      AC_DEFINE(__OSSIM_ALPHA__)
    fi
  ;;
  *-*-irix5* | *-*-irix6* )
    USE_SGI=1
    USE_SVR4=1
    AC_DEFINE(__OSSIM_SGI__)
    AC_DEFINE(__OSSIM_SVR4__)
  ;;
  *-*-solaris2* )
    USE_SUN=1
    USE_SOLARIS=1
    USE_SVR4=1
    AC_DEFINE(__OSSIM_SUN__)
    AC_DEFINE(__OSSIM_SOLARIS__)
    AC_DEFINE(__OSSIM_SVR4__)
    NEEDS_D_REENTRANT_FOR_R_FUNCS=1
  ;;
  *-*-sunos4* )
    USE_SUN=1
    USE_SUNOS=1
    USE_BSD=1
    AC_DEFINE(__OSSIM_SUN__)
    AC_DEFINE(__OSSIM_SUNOS__)
    AC_DEFINE(__OSSIM_BSD__)
  ;;
  *-*-freebsd*)
    USE_BSD=1
    USE_FREEBSD=1
    AC_DEFINE(__OSSIM_FREEBSD__)
    AC_DEFINE(__OSSIM_BSD__)
  ;;
  *-*-openbsd*)
    USE_BSD=1
    USE_OPENBSD=1
    AC_DEFINE(__OSSIM_FREEBSD__)
    AC_DEFINE(__OSSIM_OPENBSD__)
  ;;
  *-*-netbsd*)
    USE_BSD=1
    USE_NETBSD=1
    AC_DEFINE(__OSSIM_FREEBSD__)
    AC_DEFINE(__OSSIM_NETBSD__)
  ;;
  *-*-osf* )
    USE_ALPHA=1
    USE_OSF=1
    AC_DEFINE(__OSSIM_ALPHA__)
    AC_DEFINE(__OSSIM_OSF__)
    NEEDS_D_REENTRANT_FOR_R_FUNCS=1
  ;;
  *-*-dgux5* )
    USE_ALPHA=1
    USE_SVR4=1
    AC_DEFINE(__OSSIM_ALPHA__)
    AC_DEFINE(__OSSIM_SVR4__)
  ;;
  *-*-sysv5* )
    USE_SYSV=1
    USE_SVR4=1
    AC_DEFINE(__OSSIM_SYSV__)
    AC_DEFINE(__OSSIM_SVR4__)
  ;;
  *-*-aix* )
    USE_AIX=1
    USE_SYSV=1
    USE_SVR4=1
    dnl Irvin Probst <irvin.probst@fr.thalesgroup.com> reports that the shared
    dnl libraries under AIX have the same suffix as the normal ones
    SO_SUFFIX=a
    AC_DEFINE(__OSSIM_AIX__)
    AC_DEFINE(__OSSIM_SYSV__)
    AC_DEFINE(__OSSIM_SVR4__)
  ;;

  *-*-cygwin* | *-*-mingw32* )
    SO_SUFFIX=dll
    PROGRAM_EXT=".exe"
    RESCOMP=windres
    AC_DEFINE(__OSSIM_CYGWIN__)
    USE_CYGWIN=1
  ;;

  *-pc-msdosdjgpp )
    USE_UNIX=0
    USE_DOS=1
    AC_DEFINE(__OSSIM_DOS__)
    PROGRAM_EXT=".exe"
    dnl DJGPP needs explicit -lstdc++ for some reason (VS: mayb some versions only?)
    LIBS="$LIBS -lstdc++"
  ;;

  *-pc-os2_emx | *-pc-os2-emx )
    AC_DEFINE(__OSSIM_EMX__)
    PROGRAM_EXT=".exe"
    LIBS="$LIBS -lstdcpp"
  ;;

  powerpc-*-darwin* )
    dnl PowerPC Darwin based distributions (including Mac OS X)
    USE_BSD=1
    USE_DARWIN=1
    SO_SUFFIX=dylib
    AC_DEFINE(__OSSIM_BSD__)
    AC_DEFINE(__OSSIM_DARWIN__)
    AC_DEFINE(__OSSIM_POWERPC__)
    CARBON="-DCARBON"
  ;;

  *-*-beos* )
    dnl leave USE_UNIX on - BeOS is sufficiently Unix-like for this
    USE_BEOS=1
    AC_DEFINE(__OSSIM_BEOS__)
  ;;

  *)
    AC_MSG_ERROR(unknown system type ${host}.)
esac

AC_SUBST(CARBON)

dnl Checks for programs.
dnl AC_PROG_CC
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_CHECK_PROG(AR, ar, ar, ar)
AC_CHECK_PROG(ECHO, echo, echo, echo)
AC_CHECK_PROG(RM, rm, rm, rm)
AC_CHECK_PROG(STRIP, strip, strip, strip)
AC_CHECK_PROG(DIRNAME, dirname, dirname)

dnl AC_LD_SHARED

dnl We will define a standard system lib variable
dnl that will check all standard libraries

# This library may be required by Python 2.0
AC_CHECK_LIB(util, openpty)

AC_CHECK_LIB(dl, dlopen) dnl , STD_LIBS="$STD_LIBS -ldl")
AC_CHECK_LIB(m, sin) dnl , STD_LIBS="$STD_LIBS -lm")
AC_CHECK_LIB(z, main) dnl , STD_LIBS="$STD_LIBS -lz")
AC_CHECK_LIB(png, main) dnl , STD_LIBS="$STD_LIBS -lpng")
AC_CHECK_LIB(gif, main) dnl , STD_LIBS="$STD_LIBS -lgif")
AC_CHECK_LIB(jpeg, main) dnl , STD_LIBS="$STD_LIBS -ljpeg")
AC_CHECK_LIB(tiff, _TIFFmalloc) dnl , STD_LIBS="$STD_LIBS -ltiff")

dnl AC_SUBST(STD_LIBS, $STD_LIBS)

dnl Now check the LONG LONG support
AC_CHECK_SIZEOF(long long, 8)
if test "$ac_cv_sizeof_long_long" != "0"; then
   AC_DEFINE(HAVE_LONG_LONG)
   echo "Defining HAVE_LONG LONG to 1 in ossimConfig.h"
fi

dnl We really need a relatively recent libtiff, at least a 3.5.x version.
dnl AC_CHECK_LIB(tiff, TIFFReadRGBATile)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T

OSSIM_TOP=`pwd`
TOP=$OSSIM_TOP
export OSSIM_TOP
export TOP

AC_SUBST(OSSIM_TOP,$OSSIM_TOP)

OSSIM_CHECK_WXPREFIX
OSSIM_CHECK_WXCONFIG

if test "$WX_SETTING" = "1" ; then

   LIBOSSIMGUI="-lossimgui"
   AC_SUBST(LIBOSSIMGUI, $LIBOSSIMGUI)
fi

AC_CHECK_APP_LINK_FLAGS

dnl ---------------------------------------------------------------------------
dnl Python Checks
dnl ---------------------------------------------------------------------------
dnl these are killing cygwin so I comented them out
dnl and hardcoded a disabled python

dnl OSSIM_PATH_PYTHON
dnl OSSIM_INIT_PYEXEC_MOD
PYTHON_INCLUDES=
PYTHON_LIBS=
PYTHON=
PYTHON_SETTING=0
export PYTHON_SETTING
AC_SUBST(PYTHON_SETTING)
AC_SUBST(PYTHON_INCLUDES)
AC_SUBST(PYTHON_LIBS)
AC_SUBST(PYTHON)

if test "$PYTHON" != no -a -f "$pythonlib" ; then
  PYTHON_LIBS=$pythonlib
  PYTHON_SETTING=1
  echo "found $PYTHON_LIBS, python enabled."
fi

dnl --------------------------------
dnl Check for the grass package...
dnl --------------------------------
OSSIM_CHECK_LIBGRASS

dnl --------------------------------
dnl Check for the geotiff package...
dnl --------------------------------
OSSIM_CHECK_MPI

dnl -------------------------------
dnl allow one to point the libtiff somewhere else
dnl -------------------------------
OSSIM_CHECK_LIBTIFF

dnl --------------------------------
dnl Check for the geotiff package...
dnl --------------------------------
OSSIM_CHECK_GEOTIFF

OSSIM_CHECK_DEBUG
OSSIM_CHECK_OPTIMIZATION
OSSIM_CHECK_WX_OGL

OSSIM_CHECK_FREETYPE
OSSIM_CHECK_GDAL
dnl OSSIM_CHECK_GIF
dnl OSSIM_CHECK_PNG


dnl
dnl  Now setup the ossim-config file for install locations
dnl  

OSSIM_CORE_LIBS="-linit -lplugin -lparallel -lscripts -lvec -limaging -lprojections -lelevation -lossim_support_data -lvpfutil -lfont -lbase -lpolyclip -lmatrix -liso8211 -lvec"

OSSIM_GUI_LIBS="-lossimgui"
ADDITIONAL_GUI_LIBS=

if test "$USE_CYGWIN" = "1" ; then
 ADDITIONAL_GUI_LIBS="-lrpcrt4 -loleaut32 -lole32 -luuid -lwinspool -lwinmm -lshell32 -lcomctl32 -lctl3d32 -ladvapi32 -lwsock32 -lkernel32 -luser32 -lgdi32 -lcomdlg32"
fi

AC_SUBST(OSSIM_CORE_LIBS, $OSSIM_CORE_LIBS)
AC_SUBST(OSSIM_GUI_LIBS, $OSSIM_GUI_LIBS)
AC_SUBST(ADDITIONAL_GUI_LIBS)

INSTALL_OSSIM_LIBS="$OSSIM_INIT_LIB $LIBGRASS_LIB_PATH $MPI_LIB_PATH $FREETYPE_LIB_PATH -L$prefix/lib/ossim $OSSIM_CORE_LIBS   $MPI_LIBS $FREETYPE_LIBS $LIBGRASS_LIBS   $GDAL_LIBS  $GEOTIFF_LIB_PATH $LIBTIFF_LIB_PATH $GEOTIFF_LIBS $LIBS"

INSTALL_OSSIM_NO_GUI_LIBS="$OSSIM_INIT_LIB $LIBGRASS_LIB_PATH $MPI_LIB_PATH $FREETYPE_LIB_PATH -L$prefix/lib/ossim $OSSIM_CORE_LIBS   $MPI_LIBS $FREETYPE_LIBS $LIBGRASS_LIBS   $GDAL_LIBS  $GEOTIFF_LIB_PATH $LIBTIFF_LIB_PATH $GEOTIFF_LIBS $LIBS"

INSTALL_OSSIM_INCLUDES="$FREETYPE_INCLUDES $LIBTIFF_INCLUDE_PATH $MPI_INCLUDES $CPL_INCLUDES -I$prefix/include/ossim $GEOTIFF_INCLUDE_PATH $LIBGRASS_INCLUDE"

INSTALL_OSSIM_GUI_LIBS="-L$prefix/lib/ossim -lossimgui $WX_LIBS $ADDITIONAL_GUI_LIBS"
INSTALL_OSSIM_GUI_INCLUDES="-I$prefix/include/ossim/ogl $WX_INCLUDES"


INSTALL_OSSIM_CFLAGS="$DEBUG_FLAG $DEFS $OSSIM_USE_WX_GUI $OPTIMIZATION_FLAG -Wall -Wno-deprecated -pipe -fPIC $MPI_DEFINES $FREETYPE_DEFINES $GDAL_DEFINES"
INSTALL_OSSIM_NO_GUI_CFLAGS="$DEBUG_FLAG $DEFS $OPTIMIZATION_FLAG -Wall -Wno-deprecated -pipe -fPIC $MPI_DEFINES $FREETYPE_DEFINES $GDAL_DEFINES"
INSTALL_OSSIM_CPP_FLAGS=""

if test $WX_SETTING = 1 ; then
     INSTALL_OSSIM_LIBS="$INSTALL_OSSIM_GUI_LIBS $INSTALL_OSSIM_LIBS"
     INSTALL_OSSIM_INCLUDES="$INSTALL_OSSIM_GUI_INCLUDES $INSTALL_OSSIM_INCLUDES"
fi

INSTALL_OSSIM_NO_GUI_INCLUDES="$INSTALL_OSSIM_INCLUDES"

AC_SUBST(VERSION)
AC_SUBST(INSTALL_OSSIM_CFLAGS)
AC_SUBST(INSTALL_OSSIM_NO_GUI_CFLAGS)
AC_SUBST(INSTALL_OSSIM_CPP_FLAGS)
AC_SUBST(INSTALL_OSSIM_NO_GUI_CPP_FLAGS)
AC_SUBST(INSTALL_OSSIM_LIBS)
AC_SUBST(INSTALL_OSSIM_NO_GUI_LIBS)
AC_SUBST(INSTALL_OSSIM_INCLUDES)
AC_SUBST(INSTALL_OSSIM_NO_GUI_INCLUDES)

dnl
dnl Output all files
dnl

AC_OUTPUT(
Makefile.common 
src/apps/ossim-config
)